【SKYRIM】Skyrim uploader落ちてない？

ついさっき気付いたんだが、おま環かもしれんから誰か確かめてくれ

落ちてる。最近始めたばかりだからてっきり閉鎖済みなのかと思ったよ。

ありがとう、一週間経っても復旧してないのか…

レターボックスの件はこちらで

質全531のレターボックスを質問した者です

環境はSE 1.6.1170です
Reshadeは一旦アンインストールしてCSのみ使っています
よろしくお願いします

>>5
[前提MOD]
SKSE
Address Library for SKSE Plugins

VR以外の全てのバージョンで動作するはずです
おそらくCS環境でも問題無いと思います。Reshadeも併用できるかも
使い方はMCMを見れば分かります
付属のREADMEは一度目を通してください

ゲームの言語設定がJAPANESEなら翻訳は不要です
ENGLISHなら "interface\translations\SimpleLetterbox_English.txt" の中身を SimpleLetterbox_japanese.txt のものに置き換えてください

こちらの環境は、SE1.5.97, モニタ解像度はWQHDです
バニラとENB環境で動作確認済みです
ただし突貫で作ったのでテストは十分ではありません
あなたのモニタ解像度と動作結果を教えてください

下記のURLからダウンロードしてください(NGワードで弾かれるので全角にしています)
ダウンロードパスワードはskyrimです
ＷＷＷ.ＡＸＦＣ.ＮＥＴ/Ｕ/４１１８４８７

>>6
WQHDで問題なく(MCMも)動きました
CSの効果で変な色になったりもしませんでした
ありがとうございます
大変、感謝です

素手攻撃のMOD作成についてはこちら

>>8
全力スレ662です
かなり興味あります！
是非よろしくお願いします！

>>9
一から作り直したのでいろいろ名称が変わっています
esp名:UnarmedCombatEvolution.esp
スクリプト名:UCE_UnarmedProgression

【重要】前提MODにDylbills Papyrus Functions(DbMiscFunctions)が追加されました。先にインストールしておいてください。URLは最後にあります
コンパイルを通すためにはSourceフォルダにこのMODのpscが必要です

>>9
UnarmedCombatEvolution.espにUnarmed Combat ScalingのPerkを移植した状態からスタートです

[Creation Kit]
1. UnarmedCombatEvolution.espをAvtive Filseとしてロード

<FormList作成>
2. Object Window > Miscellaneous > FormListから新たに空のFormListを二つ作成。EditorIDは次の通り
UCE_ExplosiveSpellList
UCE_NonExplosiveSpellList

<Global Value作成>
3. Object Window > Miscellaneous > Globalから新たなGlobal Valueを作成
Variable Type: Float
Value: 1.0
ID: UCE_ExpMultiplier

<Magic Effect作成>
4. Object Window > Magic > Magic Effectから新たなMagic Effectを作成
IDとName: UnarmedScalingPerk_MGEF
Effect Archetype: Script
Casting Type: Constant Effect(永久効果)
Delivery: Self(自己)
Hide in UIにチェック

<Spell作成>
5. Object Window > Magic > Spellから新たなSpellを作成
IDとName: UnarmedScalingPerk_Ab
Type: Ability(特殊能力)
Casting : Constant Effect(永久効果)
Delivery: Self(自己)

6. Effectsエリアで右クリックしてNew→UnarmedScalingPerk_MGEFを追加

>>9
<Perkにアビリティを追加>
7. Object Window > Actor > PerkからUnarmedScalingを開く
8. Perk Entries内で右クリックしてNew→Abilityにチェック→プルダウンからUnarmedScalingPerk_Abを選択

<Magic Effectにスクリプトをアタッチ>
9. Object Window > Magic > Magic EffectからUnarmedScalingPerk_MGEFを開く
10. 右下のPapyrus ScriptsのAddボタンをクリック
11. [New Script]をダブルクリック
12. NameをUCE_UnarmedProgressionとしてOKする
13. Magic Effect画面右下に追加されたUCE_UnarmedProgressionを右クリックしてEdit Source
14. ScriptName UCE_UnarmedProgression Extends ActiveMagicEffectの下一行開けて以下のコードをコピペ

>>9
Actor Property PlayerRef Auto
Float Property BaseExpAmount = 10.0 Auto
Float Property MaxLevelBonusMult = 2.0 Auto
Float Property MaxArmorBonusMult = 2.0 Auto
FormList Property UCE_ExplosiveSpellList Auto
FormList Property UCE_NonExplosiveSpellList Auto
GlobalVariable Property UCE_ExpMultiplier Auto
Int Property HitGuardDurationID = 1 Auto Hidden
Int Property RequiredUnarmedCount = 2 AutoReadOnly
Float Property HitGuardDuration = 0.15 Auto Hidden
Weapon Property Unarmed Auto

Bool isGuardActive = False
Int cachedPlayerLevel
Float cachedGlobalExpMult

Event OnPlayerLoadGame()
RegisterForSingleUpdate(0.1)
EndEvent

Event OnRaceSwitchComplete()
RegisterForSingleUpdate(1.0)
EndEvent

Event OnEffectStart(Actor akTarget, Actor akCaster)
If akTarget == PlayerRef
ResetCacheAndRegister()
EndIf
EndEvent

Event OnUpdate()
ResetCacheAndRegister()
EndEvent

>>9
Function ResetCacheAndRegister()
PO3_Events_AME.RegisterForMagicHit(Self)
PO3_Events_AME.RegisterForWeaponHit(Self)
PO3_Events_AME.RegisterForLevelIncrease(Self)

isGuardActive = False
cachedPlayerLevel = PlayerRef.GetLevel()
cachedGlobalExpMult = UCE_ExpMultiplier.GetValue()
UCE_ExplosiveSpellList.Revert()
UCE_NonExplosiveSpellList.Revert()
EndFunction

Event OnLevelIncrease(int aiLevel)
cachedPlayerLevel = aiLevel
EndEvent

Event OnTimer(int aiTimerID)
If aiTimerID == HitGuardDurationID
isGuardActive = False
EndIf
EndEvent

>>9
Event OnMagicHit(ObjectReference akTarget, Form akSource, Projectile akProjectile)
If UCE_NonExplosiveSpellList.HasForm(akSource)
Return
EndIf

If UCE_ExplosiveSpellList.HasForm(akSource)
StartHitGuard()
Return
EndIf

Spell spellHit = akSource As Spell
If spellHit && HasExplosion(spellHit)
StartHitGuard()

ElseIf spellHit
UCE_NonExplosiveSpellList.AddForm(spellHit)
EndIf
EndEvent

Function StartHitGuard()
isGuardActive = True
DbActiveMagicEffectTimer.StartTimer(Self, HitGuardDuration, HitGuardDurationID)
EndFunction

>>9
Event OnWeaponHit(ObjectReference akTarget, Form akSource, Projectile akProjectile, Int aiHitFlagMask)
If !akTarget || isGuardActive || akSource != Unarmed
Return
EndIf

Actor targetActor = akTarget As Actor
If !targetActor || targetActor.IsDead()
Return
EndIf

Float currentTargetLevel = targetActor.GetLevel()
Float currentLevelDiff = currentTargetLevel - cachedPlayerLevel
Float finalExp = BaseExpAmount

; レベル差ボーナス
Float levelBonusMult = 1.0
If currentLevelDiff > 0
levelBonusMult = 1.0 + (currentLevelDiff * 0.1)

If levelBonusMult > MaxLevelBonusMult
levelBonusMult = MaxLevelBonusMult
EndIf
EndIf

finalExp = finalExp * levelBonusMult

; 防御値ボーナス
Float targetArmor = targetActor.GetActorValue("DamageResist")
Float armorBonusMult = 1.0 + (targetArmor * 0.005)

If armorBonusMult > MaxArmorBonusMult
armorBonusMult = MaxArmorBonusMult
EndIf
finalExp = finalExp * armorBonusMult

; ユーザー設定倍率
finalExp = finalExp * cachedGlobalExpMult
Game.AdvanceSkill("LightArmor", finalExp)
EndEvent

>>9
Bool Function HasExplosion(Spell akSpell)
Int i = akSpell.GetNumEffects()
While i > 0
i -= 1
MagicEffect me = akSpell.GetNthEffectMagicEffect(i)
If me && me.GetExplosion()
UCE_ExplosiveSpellList.AddForm(akSpell)
Return True
EndIf
EndWhile

Return False
EndFunction

>>9
15. Ctrl+Sで保存。下にCompilation succeeded.が表示されたことを確認する
16. スクリプト編集画面を閉じる

17. Magic Effect画面右下のUCE_UnarmedProgressionを選択、右にあるPropertiesボタンをクリック
18. Auto-Fill Allボタンをクリック。5 properties auto-filledと表示されたことを確認する

19. メイン画面上部メニュー > FILE > Compact Active File From IDs
20. セーブして終了

※パークツリーの改変はあなたが以前やったようにしてください

>>9
[xEdit]
1. UnarmedCombatEvolution.espをロード
2. 左ペインでUnarmedCombatEvolution.espを選択、右ペインのRecord FlagsにESLフラグがあることを確認
3. 左ペインのUnarmedCombatEvolution.espを右クリックしてCheck for Errorsを実行。右ペインにErrors found: 0と表示されたことを確認

[パッケージとインストール]
作成したesp, pex, pscをまとめてzip圧縮してMOD管理ツールでインストール
フォルダ構成は以下の通り
Unarmed Combat Evolution\UnarmedCombatEvolution.esp
Unarmed Combat Evolution\Scripts\UCE_UnarmedProgression.pex
Unarmed Combat Evolution\Source\Scripts\UCE_UnarmedProgression.psc

[動作確認]
以下をチェックします
・Perkを取得していないときは素手攻撃では何も起こらない
・取得後は素手攻撃で軽装経験値が上昇。武器や魔法では上がらない

テストは十分とは言えませんがおそらく大丈夫だと思います

Dylbills Papyrus Functions
www.nexusmods.com/skyrimspecialedition/mods/65410

>>9
補足
Papyrus Extenderは依然として必要です
コンパイルが通らないときはSKSEのpscがsourceフォルダにあるか確認してください。SKSEのpscはバニラの同名pscを上書きします

>>9
訂正
味方を除外するのを忘れていました
OnWeaponHitイベントを以下のように変更します

変更前:
If !targetActor || targetActor.IsDead()
Return
EndIf

変更後:
If !targetActor || targetActor.IsDead() || targetActor.IsPlayerTeammate()
Return
EndIf

>>9
ミスがあったので訂正
プロパティのRequiredUnarmedCountは消し忘れです
Int Property RequiredUnarmedCount = 2 AutoReadOnlyの行はスクリプトから削除していいです

>>22
最後のは未反映ですが問題なく動作することを確認済みです
かなり良い感じで勉強になりました
ありがとうございました！